Mac vers ISO

version 2003 (Modifiée)

Mac vers ISO (texte) Chaîne

Mac vers ISO retourne un texte équivalent à celui passé dans le paramètre texte mais exprimé à l'aide de la table de caractères Web définie dans le menu Jeu standard de la page Web/Configuration des Préférences de l'application. Par défaut, le jeu de caractères ISO Latin-1 (ISO-8859-1) est utilisé :

Cette commande attend un paramètre de type texte exprimé à l'aide de la table ASCII Mac OS.

Vous n'aurez généralement pas besoin d'utiliser cette commande. 4D convertit, dans les deux sens, les caractères reçus et envoyés par les navigateurs Web. En résultat, les valeurs textes que vous manipulez, à l'intérieur d'un process de connexion Web, sont toutes exprimées à l'aide de la table ASCII Mac OS.

Dans 4D, chaque valeur, champ ou variable de texte est encodé sur la base de la table ASCII Mac OS sous Macintosh et Windows, dans la mesure où vous ne les avez pas convertis à l'aide d'un filtre ASCII. Pour plus d'informations sur ce point, référez-vous à la section Codes ASCII.

Sous Windows, vous n'avez pas besoin de vous préoccuper de la conversion des codes ASCII. Lorsque vous copiez ou collez du texte entre 4D et Windows ou lorsque vous importez/exportez des données, 4D effectue automatiquement ces conversions. Cependant, lorsque vous utilisez des commandes de lecture/écriture telles que ENVOYER PAQUET ou RECEVOIR PAQUET, 4D n'effectue aucune conversion de code ASCII.

Par conséquent, quelle que soit la plate-forme sur laquelle vous travaillez, si vous voulez écrire sur disque des documents HTML ISO Latin-1 ou utilisant d'autres jeux de caractères Web, vous avez juste besoin de convertir le texte à l'aide de la fonction Mac vers ISO. C'est en fait le principal rôle de cette commande.

Sous Windows, dans ce cas, vous ne devez pas filtrer les caractères à l'aide d'un filtre d'exportation ASCII.

(1) La ligne suivante convertit par défaut le texte encodé Mac OS stocké dans vtTexte en texte encodé ISO-Latin 1 :

   vtTexte:=Mac vers ISO(vtTexte)

(2) Lors du développement d'une application 4D Web Server, vous créez par programmation des pages HTML que vous enverrez par la suite sur Intranet ou Internet à l'aide de la commande ENVOYER FICHIER HTML. Dans certains de ces documents se trouvent des références ou des liens vers d'autres documents. La méthode projet ci-dessous calcule le chemin d'accès HTML à partir du chemin d'accès Windows ou Macintosh reçu en paramètre :

      ` Méthode projet Chemin HTML
      ` Chemin HTML ( Texte ) -> Texte
      ` Chemin HTML ( Chemin d'accès du gestionnaire de fichier natif ) -> Chemin d'accès HTML

   C_TEXTE($0;$1)
   C_ENTIER LONG($vlCar;$vlAscii)
   C_ALPHA(31;$vsCar)

   $0:=""
   Si (Sous Windows )
      $1:=Remplacer chaine($1;"\";"/")
   Sinon 
      $1:=Remplacer chaine($1;":";"/")
   Fin de si 
   $1:=Mac vers ISO($1)
   Boucle ($vlCar;1;Longueur($1))
      $vlAscii:=Code ascii($1[[$vlCar]])
      Au cas ou 
         : ($vlAscii>=127)
            $vsCar:="%"+Sous chaine(Chaine($vlAscii;"&$");2)
         : (Position(Caractere($vlAscii);":<>&%= "+Caractere(34))>0)
            $vsCar:="%"+Sous chaine(Chaine($vlAscii;"&$");2)
      Sinon 
         $vsCar:=Caractere($vlAscii)
      Fin de cas 
      $0:=$0+$vsCar
   Fin de boucle 

Note : La méthode projet Sous Windows est listée dans la section Présentation des documents système.

Une fois cette méthode projet placée dans votre base, si vous voulez inclure une liste de liens FTP vers des documents présents dans un répertoire particulier, vous pouvez écrire par exemple :

      ` Variables interprocess définies, par exemple, dans la méthode base Sur ouverture
   <>vsFTPURL:="ftp://123.4.56.78/Spiders/"
   <>vsFTPDirectory:="APS500:Spiders:" ` Ici, un chemin du gestionnaire de fichier Mac OS
      ` ...

      ` ...
   TABLEAU ALPHA(31;$asDocuments;0)
   LISTE DES DOCUMENTS(...;$asDocuments)
   $vlNbDocuments:=Taille tableau($asDocuments)
   jsHandler:=...
   Boucle ($vlDocument;1;$vlNbDocuments)
      vtHTMLCode:=vtHTMLCode+"<P>Caractere(34)+<>vsFTPURL+Chemin HTML (Sous chaine 
               ($1+$asDocuments{$vlDocument}; Longueur (<>vsFTPDirectory)+1)) + Caractere(34)+ 
                 jsHandler+"> "+$asDocuments{$vlDocument}+"</P>"+Caractere(13)
   Fin de boucle
      ` ...

Codes ASCII, ENVOYER FICHIER HTML, ENVOYER PAQUET, ISO vers Mac, UTILISER FILTRE.