Mac to ISO

Version 2003 (Geändert)

Mac to ISO (Text) String

Die Funktion Mac to ISO gibt Text zurück, der in den Zeichensatz konvertiert wurde, der unter den Datenbankeinstellungen auf der Seite Web/Konfiguration als Standardsatz definiert wurde. Das ist für die internationale, französische und deutsche Version der Zeichensatz ISO Latin-1 (ISO-8859-1).

Diese Funktion erwartet einen Parameter Text mit dem MacOS ASCII Zeichensatz.

4D konvertiert die Zeichen, die er von einem Web Browser erhält oder an ihn sendet. Deshalb werden die entsprechenden Werte innerhalb einer Web Verbindung immer mit dem MacOS ASCII Zeichensatz dargestellt.

Sie müssen diese Funktion, wenn Sie unter Windows arbeiten, normalerweise nicht einsetzen. 4D führt die Konversion automatisch durch, wenn Sie Text zwischen 4D und Windows kopieren und einsetzen. Verwenden Sie dagegen Lese/Schreibbefehle wie SEND PACKET oder RECEIVE PACKET, müssen Sie die ASCII Konvertierung explizit aufrufen.

In 4D haben alle Felder, Variablen oder Werte vom Typ Text unter Windows und auf Macintosh standardmäßig den ASCII Zeichensatz für MacOS, außer sie wurden in einen anderen ASCII Zeichensatz konvertiert.

In diesem Fall dürfen Sie unter Windows die Zeichen nicht mit einer ASCII Ausgabetabelle filtern.

Wollen Sie HTML-Dokumente im ISO Latin-1 Zeichensatz auf die Festplatte schreiben, müssen Sie, unabhängig von der Plattform, den Text konvertieren. Dafür verwenden Sie die Funktion Mac to ISO.

1. Folgende Zeile konvertiert den in MacOS kodierten Text in vtSomeText standardmäßig in einen in ISO-Latin 1 kodierten Text:

   vtSomeText:=Mac to ISO(vtSomeText)

2. Beim Entwickeln einer 4D Web Server Anwendung erstellen Sie HTML Dokumente, die Sie später mit dem Befehl SEND HTML FILE über Intranet oder Internet senden. Einige dieser Dokumente haben Referenzen oder Links zu anderen Dokumenten.

Folgende Projektmethode berechnet für HTML einen Pfadnamen aus dem als Parameter erhaltenen Pfadnamen für Windows oder Macintosh.

      ` Projektmethode HTML Pfadname 
      ` HTML Pfadname ( Text ) -> Text
      ` HTML Pfadname ( Native File Manager Pfadname ) -> HTML Pfadname

   C_TEXT($0;$1)
   C_LONGINT($vlChar;$vlAscii)
   C_STRING(31;$vsChar)

   $0:=""
   If (On Windows )
      $1:=Replace string($1;"\";"/")
   Else 
      $1:=Replace string($1;":";"/")
   End if 
   $1:=Mac to ISO($1)
   For ($vlChar;1;Length($1))
      $vlAscii:=Ascii($1[[$vlChar]])
      Case of 
         : ($vlAscii>=127)
            $vsChar:="%"+Substring(String($vlAscii;"&$");2)
         : (Position(Char($vlAscii);":<>&%= "+Char(34))>0)
            $vsChar:="%"+Substring(String($vlAscii;"&$");2)
      Else 
         $vsChar:=Char($vlAscii)
      End case 
      $0:=$0+$vsChar
   End for 

Hinweis: Die Projektmethode On Windows finden Sie im Abschnitt Systemdokumente.

Gibt es diese Projektmethode in Ihrer Datenbank und wollen Sie eine Reihe FTP Links in Dokumenten aus einem speziellen Verzeichnis einbinden, schreiben Sie:

      ` Menge Interprozeßvariablen, beispielsweise in der Datenbankmethode On Startup
   <>vsFTPURL:="ftp://123.4.56.78/Spiders/"
   <>vsFTPDirectory:="APS500:Spiders:" ` Hier ein MacOS File Manager Pfadname
      ` ...

      ` ...
   ARRAY STRING(31;$asDocuments;0)
   DOCUMENT LIST(...;$asDocuments)
   $vlNbDocuments:=Size of array($asDocuments)
   jsHandler:=...
   For ($vlDocument;1;$vlNbDocuments)
      vtHTMLCode:=vtHTMLCode+"<P>Char(34)+<>vsFTPURL
         +HTML Pathname (Substring($1+$asDocuments{$vlDocument};
         Length(<>vsFTPDirectory)+1)) +Char(34)+jsHandler+">
          "+$asDocuments{$vlDocument}+"</P>"+Char(13)
   End for
      ` ...

ASCII Codes, ISO to Mac, SEND HTML FILE, SEND PACKET, USE ASCII MAP.