PV SET STYLE PROPERTY

Version 6.8

PV SET STYLE PROPERTY (Bereich; Stil; Eigenschaft; Wert)

Der Befehl PV SET STYLE PROPERTY setzt den Wert von Eigenschaft für die Stilvorlagen mit den in Stil angegebenen Referenznummern.

Für den Parameter Eigenschaft verwenden Sie eine Konstante unter dem Thema PV Stil Eigenschaften, für den Parameter Wert eine Konstante unter dem Thema PV Stil Werte. Die Wahl der Konstante für Wert richtet sich nach der Wahl für Eigenschaft.

Weitere Informationen dazu finden Sie in der Beschreibung zum Befehl PV SET CELL PROPERTY.

Wollen Sie die Eigenschaften standardmäßiger Stilvorlagen bearbeiten, übergeben Sie im Parameter Stil eine Konstante unter dem Thema PV Stil spezielle Werte:

• pv style cells: Standardmäßige Stilvorlage für Zellen (genannt "Zellen").

• pv style col row headers: Standardmäßige Stilvorlage für Spalten- und Zeilentitel (genannt "Spalten-/Zeilentitel").

• pv style page footer header: Standardmäßige Stilvorlage für gedruckte Kopf- und Fußteile auf der Seite (genannt "Kopf- & Fußteil Seite").

Hinweis: Sie können diese Stilvorlagen im 4D View Menü Stil mit dem Befehl Stilvorlagen bearbeiten.

Mit dieser Methode können Sie Eigenschaften für einen neuen Stil definieren. Wir setzen einen Wert für jeden der drei anzupassenden Stileigenschaften:

• Die Eigenschaft "horizontale Ausrichtung" wird zu "links ausgerichtet",

• Die Eigenschaft "vertikale Ausrichtung" wird zu "zentriert",

• Die Eigenschaft "Rotation" wird zu "90 Grad".

   ARRAY LONGINT($ArrayProps;3)  `Array mit Stileigenschaften
   ARRAY LONGINT($ArrayValues;3)  `Wert für jede Eigenschaft

   C_STRING(255;$StyleName)  `Name des hinzuzufügenden Stils für Bereich

   ARRAY LONGINT($StyleNumArray;0)  `Array mit Stilnummern
   ARRAY STRING(255;$StyleNameArray;0)  `Array mit Stilnamen
   C_INTEGER($Index)  `Schleife Index
   C_INTEGER($Position)  `Position des neuen Stils in den Arrays mit Nummern und Namen

      `Initialisierung
   $ArrayProps{1}:=pv style hor alignment   `Dazugehörige Eigenschaften...
   $ArrayProps{2}:=pv style vert alignment 
   $ArrayProps{3}:=pv style rotation 

   $ArrayValues{1}:=pv value hor alignment left   `...und Werte
   $ArrayValues{2}:=pv value hor alignment center 
   $ArrayValues{3}:=pv value rotation 90 

   $StyleName:="Unterabschnitt"

   PV GET STYLE LIST (Bereich;$StyleNumArray;$StyleNameArray)  
                                       `Liste der vorhandenen Stile

   If (Find in array($StyleNameArray;$StyleName)=-1)  `Existiert der Stil noch nicht?
      $Position:=Size of array($StyleNameArray)+1  `Hinzufügen
      INSERT ELEMENT ($StyleNameArray;$Position)  `Array anpassen
      INSERT ELEMENT ($StyleNumArray;$Position)
      $StyleNameArray{$Position}:=$StyleName  `Name des neuen Stils zuweisen
      $StyleNumArray{$Position}:=PV Add style (Bereich;$StyleName)  
                                    `Nummer des neuen Stils zuweisen

      For ($Index;1;Size of array($ArrayProps))  `Für alle zu setzenden Eigenschaften
            `Eigenschaft hat nicht den gewünschten Wert?
         If (PV Get style property (Bereich;$StyleNumArray{$Position};
                                    $ArrayProps{$Index})#$ArrayValues{$Index})
            `Richtigen Wert zuweisen
            PV SET STYLE PROPERTY (Bereich;$StyleNumArray{$Position};
                                    $ArrayProps{$Index};$ArrayValues{$Index})
         End if
      End for   `Array $ArrayProps für Stilvorlagen Eigenschaften erneut prüfen

   Else 
      ALERT("Der Stil "+$StyleName+" liegt bereits im Bereich.")
   End if

PV Get style property.

Themen PV Stil Eigenschaften und PV Stil Werte