PICTURE TO GIF

Version 6.7 (Geändert)

PICTURE TO GIF (Pict; BlobGIF)

Mit dem Befehl PICTURE TO GIF erstellen Sie aus einem Bild (vom Typ PICT), das in einer Variablen oder einen 4D Feld gespeichert ist, ein Bild im GIF-Format.

In Pict übergeben Sie eine Variable oder ein 4D Feld vom Typ Bild, in BlobGIF eine Variable oder ein Feld vom Typ BLOB. Nach Ausführen des Befehls enthält BlobGIF das Bild im GIF-Format.

Hinweis: Das Bild im GIF-Format kann max. 256 Farben enthalten. Enthält das Original im PICT-Format mehr als 256 Farben, können einige Farben verloren gehen. Der Befehl reduziert die Anzahl Farben gemäß den Systemeinstellungen. Das erstellte GIF ist vom Typ 87a (nicht transparent) und normal (not interlaced).

Mit dem Befehl BLOB TO DOCUMENT können Sie das Bild in BlobGIF in einer Datei sichern, und sogar im Web publizieren.

War die Umwandlung erfolgreich, hat die Systemvariable OK den Wert 1. Andernfalls hat sie den Wert 0 (Null).

Sie möchten ein GIF Bild durch Anzeigen des Zählers für die Verbindung "on the fly" generieren. Dazu setzen Sie in der Bildbibliothek alle Nummern der Verbindung als Bilder:

In der Datenbankmethode On Web Connection schreiben Sie dann folgenden Code:

   If (Web Context)
      ...
   Else
      C_BLOB ($blob)
      Case of 
         ...
         : ($1="/4dcgi/Counter") `Erstelle GIF Zähler
               `Findet 4D dieses URL beim Senden der statischen Seite
            $blob:=gifcounter (<>nbHits)  `Berechne das GIF Bild
               `Die Variable <>nbHits enthält die Nummer der Verbindungen 
            SEND HTML BLOB ($blob;"image/gif")
               `Füge Bild ein und sende es an den Browser
            ...
      End case
   End if

Hier ist die Methode gifcounter:

   C_LONGINT($1)
   C_PICTURE($img)
   C_BLOB($0)
   If ($1=0)
      $ndigits:=1
   Else 
      $ndigits:=1+Length(String($1))
   End if
   If ($ndigits<5)
      $ndigits:=5
   End if

   $div:=10^($ndigits-1)
   For ($i;1;$ndigits)
      $ref:=Int($1/$div)%10
      GET PICTURE FROM LIBRARY($ref+1000;Bild)
      $img:=$img+Bild
      $div:=$div/10
   End for

   PICTURE TO GIF($img;$0)

Sendet 4D nun eine Seite an den Web Browser, zeigt es folgendes GIF Bild: