WR INSERT HYPERLINK

Version 6.7

WR INSERT HYPERLINK (Bereich; linkTyp; urlStil; linkBezeichnung; linkInhalt; MethRef)

Der Befehl WR INSERT HYPERLINK fügt in Bereich eine "hyperlink" Referenz ein, und zwar an der Cursor-Position oder anstelle des ausgewählten Textes.

Der Parameter linkTyp definiert die Art des einzufügenden Hypertext Links. 4D Write läßt drei Arten zu: Links vom Typ Methode, Links vom Typ URL und Links vom Typ Dokument.

• Ein Link vom Typ Methode führt eine 4D Methode aus, wenn auf die Referenz geklickt wird. Die Methode kann keine Funktion sein, es kann auch kein Parameter übergeben werden. Sie kann jedoch Werte empfangen in $1, $2 und optional in $3:

	- $1 (Lange Ganzzahl) enthält die Referenz des 4D Write Bereichs,
	- $2 (Text) enthält die Bezeichnung des Link,
	- $3 (Lange Ganzzahl) enthält eine willkürliche Zahl, die Sie dem Link über den Parameter MethRef oder im Benutzermodus von 4D Write zuordnen können.

Zum Kompilieren der Datenbank müssen Sie $1 und $3 als Lange Ganzzahl, $2 als Text deklarieren, auch wenn Sie diese nicht benutzen.

Um ein Link vom Typ Methode einzufügen, setzen Sie 0 in linkTyp.

• Ein Link vom Typ URL öffnet den Standard-Browser und greift auf ein spezifisches URL zu, das im Parameter linkInhalt definiert wurde. Um ein Link vom Typ URL einzufügen, setzen Sie 1 in linkTyp.

• Ein Link vom Typ Dokument ersetzt, sobald Sie auf das Link klicken, das aktuelle Dokument durch ein anderes, dessen Pfad Sie im Parameter linkInhalt übergeben haben. Es muß natürlich ein Format haben, das 4D Write erkennt. Um ein Link vom Typ Dokument einzufügen, setzen Sie 2 in linkTyp.

Mit dem Parameter urlStil können Sie die Darstellung des eingefügten Hypertext Links definieren:

• Wollen Sie die Standarddarstellung des Hyperlinks (blau und unterstrichen) beibehalten, setzen Sie 1 in urlStil. Über den Befehl WR SET DOC PROPERTY können Sie Standardfarben per Programmierung ändern.

• Wollen Sie eine eigene Darstellung verwenden, setzen Sie 0. In diesem Fall können Sie den Link auswählen und den Stil über den Befehl WR SET TEXT PROPERTY festlegen.

Setzen Sie 0, ohne einen Stil für den Link festzulegen, erscheint der Link als aktueller Text, d.h er wird nicht grafisch hervorgehoben.

Der Parameter linkBezeichnung setzt den sichtbaren Text des Links (wenn im Menü Anzeigen/Werte eingestellt ist).

Der Parameter linkInhalt enthält den Wert des Hypertext Links. Die Art des Wertes hängt von der Art des Links ab:

• Für ein Link vom Typ 4D Methode setzen Sie den Namen der Methode (z.B. "Order_Clients"),

• Für ein Link vom Typ URL setzen Sie das komplette URL (z.B. "http://www.4D.com/")

• Für ein Link vom Typ Dokument setzen Sie den vollständigen Pfad des Dokuments (z.B. unter Windows "C:\MeinOrdner\MeinDok.4w7", auf MacOS "Festplatte:MeinOrdner:MeinDok").

Über den Parameter MethRef können Sie, wenn der Link vom Typ 4D Methode ist, der aufgerufenen Methode einen zusätzlichen Wert hinzufügen. Die Methode empfängt diesen Wert im Parameter $3 (vom Typ Lange Ganzzahl).

(1) Sie möchten das URL Ihrer Web Site in den 4D Write Bereich einsetzen:

   WR INSERT HYPERLINK(Bereich;1;"Besuchen Sie uns im Internet";"http:/www.MySite.com/")

(2) Sie möchten Ihre 4D Write Dokumente mit Hypertext Navigation ausstatten, die auf Links vom Typ Dokument basieren. Die folgende Methode verwaltet Pfadnamen dynamisch und plattformunabhängig:

   $Doc:=Strukturdatei
   Doc:=$Doc
   While (Position(":";$Doc)#0)
      $Doc:=Substring($Doc;1+Position(":";$Doc);Length($Doc))
      $Long:=Length($Doc)
   End while 
   Doc:=Substring(Doc;1;Length(Doc)-$Long)
   PLATFORM PROPERTIES($Platf;$Syst;$Computer)
   If ($Platf=Windows )
      $name:=Doc+"Dokumentation"+"/"+"01_Einleitung.4W7"
   Else 
      $name:=Doc+"Dokumentation"+":"+"01_01_Einleitung.4W7"
   End if 
   $title:="Siehe Dokumentation"
   WR INSERT HYPERLINK (WriteBereich;2;1;$title;$name)

(3) Dieses Beispiel zeigt Links vom Typ Methode. Der Benutzer soll in Ihrem Dokument in einen bestimmten Bereich Informationen eingeben können, zum Beispiel seinen Vor- und Nachnamen. Sie fügen ein Hyperlink über die Methode Hyperlink_Methode ein. Diese Methode fordert den Benutzer auf, entweder den Vor- oder Nachnamen einzugeben, je nachdem, welcher Wert in $3 übergeben wurde. Die eingegebenen Daten ersetzen dann den Link:

      `Hyperlink_Methode
   C_LONGINT($1;$3)
   C_TEXT($2)
   Case of 
      : ($3=1)
         WR INSERT TEXT ($1;Request("Geben Sie Ihren Vornamen ein"))
      : ($3=2)
         WR INSERT TEXT ($1;Request("Geben Sie Ihren Nachnamen ein"))
   End case 
   WR GET SELECTION ($1;$deb;$end)
   WR SET SELECTION ($1;$deb;$end+1)
   WR EXECUTE COMMAND ($1;wr cmd clear)

Die Methode vom Typ Hyperlink in den 4D Write Bereich eingeben:

   $title:="Klicke für Eingabe"
   $method:="Hyperlink_Methode"
   WR INSERT TEXT (Bereich;"Name: ")
   WR INSERT HYPERLINK (Bereich;0;1;$title;$method;1)
   WR INSERT TEXT (Bereich;Char(Carriage Return )+"Vorname: ")
   $title:="Eingeben"
   WR INSERT HYPERLINK (Bereich;0;1;"Klicke für Eingabe";"Hyperlink_Methode";2)

WR GET HYPERLINK.