WR INSERER LIEN HYPERTEXTE

version 6.7

WR INSERER LIEN HYPERTEXTE (zone; typeLien; styleURL; libelléLien; contenuLien; refMéthode)

La commande WR INSERER LIEN HYPERTEXTE insère dans zone une référence de type "lien hypertexte", à l'emplacement courant du curseur ou à la place de la sélection courante.

Le paramètre typeLien permet de définir le type du lien hypertexte à insérer. 4D Write admet trois types de liens hypertextes : les liens de type Méthode, les liens de type URL et les liens de type Document.

• Un lien de type Méthode permet de lancer l'exécution d'une méthode 4D lors du clic sur la référence. La méthode ne peut pas être une fonction, et il n'est pas possible de lui passer des paramètres. Elle peut toutefois recevoir deux ou trois valeurs dans $1, $2 et, optionnellement, $3 :

- $1 (Entier long) contient la référence de la zone 4D Write,

- $2 (Texte) contient le libellé du lien,

- $3 (Entier long) contient une valeur numérique arbitraire que vous aurez éventuellement associé au lien, à l'aide du paramètre refMethode ou dans le mode "Utilisation" de la base.

Note : En vue de la compilation de la base, il est nécessaire de déclarer $1 et $3 en Entier long et $2 en Texte, même si vous ne les utilisez pas.

Pour insérer un lien de type Méthode, passez 0 dans typeLien.

• Un lien de type URL permet d'ouvrir le navigateur par défaut de la machine et d'accéder à un URL spécifique, défini dans le paramètre contenuLien.

Pour insérer un lien de type URL, passez 1 dans typeLien.

• Un lien de type Document provoque, lors du clic sur le lien, le remplacement du document courant par un autre document dont le chemin d'accès a été passé dans le paramètre contenuLien. Bien entendu, le format du document à ouvrir doit être reconnu par 4D Write.

Pour insérer un lien de type Document, passez 2 dans typeLien.

Le paramètre styleURL permet de définir l'apparence du lien hypertexte inséré :

• Si vous voulez conserver l'apparence par défaut des liens hypertexte (texte bleu souligné), passez 1 dans styleURL. Les couleurs par défaut peuvent être modifiées par programmation, à l'aide de la commande WR FIXER PROPRIETE DOCUMENT.

• Si vous voulez utiliser une apparence personnalisée, passez 0. Dans ce cas, vous devrez sélectionner le lien et lui affecter un style à l'aide de la commande WR FIXER PROPRIETE TEXTE.

Si vous passez 0 et n'affectez pas de style au lien, il prendra l'apparence du texte courant (il ne sera pas graphiquement matérialisé).

Le paramètre libelléLien permet de définir le libellé visible du lien (en affichage des valeurs).

Le paramètre contenuLien contient la valeur hypertexte du lien. La nature de cette valeur dépend du type de lien :

• pour un lien de type Méthode 4D, passez le nom de la méthode (par exemple "TriClients"),

• pour un lien de type URL, passez l'URL complet (par exemple "http://www.4D.fr/"),

• pour un lien de type Document, passez le chemin d'accès absolu du document (par exemple "C:\MonDossier\MonDoc.4w7" sous Windows, ou "DisqueDur:MonDossier:MonDoc" sous Mac OS).

Le paramètre refMéthode permet, lorsque le lien est de type méthode 4D, de passer une valeur supplémentaire à la méthode appelée. La méthode recevra cette valeur dans le paramètre $3 (de type Entier long).

Note : L'insertion et la gestion de liens hypertexte est également accessible dans le mode Utilisation de 4D Write.

(1) Vous souhaitez insérer l'URL de votre site Web dans une zone 4D Write:

   WR INSERER LIEN HYPERTEXTE(zone;1;"Visitez ce superbe site";"http:/www.MonSite.com/")

(2) Dans vos documents 4D Write, vous proposez une interface de navigation hypertexte basée sur des liens de type Document. La méthode suivante gère dynamiquement les chemins d'accès, quelle que soit la plate-forme :

   $Doc:=Fichier structure
   Doc:=$Doc
   Tant que (Position(":";$Doc)#0)
      $Doc:=Sous chaine($Doc;1+Position(":";$Doc);Longueur($Doc))
      $Long:=Longueur($Doc)
   Fin tant que 
   Doc:=Sous chaine(Doc;1;Longueur(Doc)-$Long)
   PROPRIETES PLATE FORME($Platf;$Syst;$Machine)
   Si ($Platf=Windows )
      $nom:=Doc+"Documentation"+"/"+"01_Introduction.4W7"
   Sinon 
      $nom:=Doc+"Documentation"+":"+"01_Introduction.4W7"
   Fin de si 
   $titre:="Voirla documentation"
   WR INSERER LIEN HYPERTEXTE (ZoneWrite;2;1;$titre;$nom)

(3) Cet exemple illustre l'emploi des liens de type Méthode. Dans votre document, vous souhaitez que l'utilisateur puisse saisir des informations, par exemple son nom et son prénom, à des emplacements spécifiques. Pour cela, vous insérez un lien qui appelle la méthode M_LiensHypertexte. Cette méthode demande à l'utilisateur de saisir soit son nom soit son prénom, suivant la valeur passée dans $3. La valeur saisie remplace alors le lien :

      `Méthode M_LiensHypertexte
   C_ENTIER LONG($1;$3)
   C_TEXTE($2)
   Au cas ou
      : ($3=1)
         WR INSERER TEXTE ($1;Demander("Saisissez votre prénom"))
      : ($3=2)
         WR INSERER TEXTE ($1;Demander("Saisissez votre nom"))
   Fin de cas 
   WR LIRE SELECTION ($1;$deb;$fin)
   WR FIXER SELECTION ($1;$deb;$fin+1)
   WR EXECUTER COMMANDE ($1;wr cmd effacer)

Pour insérer le lien de type Méthode dans la zone 4D Write :

   $titre:="Cliquez pour saisir"
   $méthode:="M_LiensHypertexte"
   WR INSERER TEXTE (Zone;"Nom : ")
   WR INSERER LIEN HYPERTEXTE (Zone;0;1;$titre;$méthode;1)
   WR INSERER TEXTE (Zone;Caractere(Retour chariot )+"Prénom : ")
   WR INSERER LIEN HYPERTEXTE (Zone;0;1;"Cliquez pour saisir";"M_LiensHypertexte";2)

WR LIRE LIEN HYPERTEXTE.