IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)

Module de sauvegarde intégré en 4D 2004

Dans cette note technique, les dispositifs de base du module de sauvegarde intégrée dans 4D 2004 sont abordés. Nous verrons la configuration de base d'exécution de la sauvegarde et de la restauration, y compris l'utilisation du fichier d'historique. Les configurations de la sauvegarde sont stockées dans un fichier XML (backup.xml). Les informations affichées dans les préférences sont, pour la plupart, prises dans ce fichier XML. Nous pouvons alors par programmation indiquer ou récupérer les configurations de la sauvegarde en utilisant des commandes XML de 4D. Ce point est également abordé dans la note. ♪

Article lu   fois.

L'auteur

Site personnel

Liens sociaux

Viadeo Twitter Facebook Share on Google+   

Introduction

Les options de sauvegarde et de restauration sont désormais intégrées dans 4D 2004 (4e dimension et 4D Server). Ces opérations peuvent être exécutées manuellement, automatiquement, ou par programmation.

Ces nouvelles fonctionnalités, qui viennent s'intégrer, simplifient la copie de la base de données avec les fichiers nécessaires, ainsi que la restauration à l'état précédent.

Dans cette note technique, les dispositifs de base du module de sauvegarde intégrée dans 4D 2004 sont abordés. Nous verrons la configuration de l'exécution de la sauvegarde et de la restauration, y compris l'utilisation du fichier d'historique.

Vue d'ensemble

Dans les versions précédentes de 4D, les opérations de sauvegarde et de restauration étaient effectuées en utilisant le plug-in 4D Backup.

Dans 4D 2004, ces opérations sont maintenant intégrées dans l'application. Vous pouvez soit commencer une sauvegarde manuellement, soit automatiquement, ou par programmation, à partir de 4D. Vous pouvez faire une copie de la base de données n'importe quand manuellement ou employer la section « Périodicité » des Préférences de sauvegarde pour le faire à des intervalles réguliers. De nouvelles commandes peuvent être employées pour exécuter et contrôler la sauvegarde par programmation. Les paramètres de sauvegarde et de restauration sont configurés dans les Préférences de base de données. Chaque sauvegarde créée peut inclure le fichier de structure et le fichier de données ainsi que des fichiers et dossiers supplémentaires. Et si un fichier d'historique est utilisé, il est aussi automatique archivé.

Si un incident survient sur une base, la restauration permet de la récupérer à l'état précédent, en utilisant le fichier d'historique.

Configurations Sauvegarde et Préférences

Les configurations de sauvegarde sont utilisées chaque fois qu'une sauvegarde est exécutée. Dans cette section, une brève présentation des configurations de sauvegarde et des configurations des préférences sera faite.

Configuration Sauvegarde

Les configurations de sauvegarde sont placées dans la page de sauvegarde sous le thème de Sauvegarde des Préférences de l'application. Les valeurs par défaut de la sauvegarde, comme montrées ci-dessous, sont mises en place pour une utilisation standard de la sauvegarde. La modification de ces valeurs est facultative. Les configurations de sauvegarde sont définies dans deux sections : Paramètres généraux et Archive.

Image non disponible

Paramètres généraux

Dans la section Paramètres généraux, vous pouvez définir le nombre de sauvegardes à garder et demander à n'exécuter une sauvegarde que s'il y a eu une modification dans le fichier de données. Ces options vous permettent de ménager de l'espace sur votre disque dur.

L'option « Conserver uniquement les x derniers fichiers de sauvegarde » par exemple, vous permet de garder seulement un certain nombre de sauvegardes. C'est-à-dire, quand une nouvelle sauvegarde (x+1) est créée, le fichier de sauvegarde le plus ancien est effacé.

Vous pouvez choisir quand effacer la sauvegarde la plus ancienne, après ou avant la création de la sauvegarde en commutant l'option de backup « Effacer la sauvegarde la plus ancienne avant/après la sauvegarde ».

Si vous lancez le backup automatiquement en utilisant l'option Périodicité, vous pouvez aussi choisir « Sauvegarde seulement si le fichier de données a été modifié », de sorte que la sauvegarde programmée sera annulée si aucune modification n'a été faite. Dans ce cas le backup sera effectué à la prochaine échéance.

De plus, vous pouvez indiquez ce que vous souhaitez faire en cas de transaction ou si la sauvegarde a échoué. Vous pouvez soit attendre la fin d'une transaction avant de commencer la sauvegarde ou attendre un certain temps pour annuler la sauvegarde. Quand la sauvegarde est annulée, le statut du backup est considéré comme « échoué ». Ainsi, vous pouvez implémenter certains mécanismes lorsque le backup échoue. Ces options sont soit de retenter à la prochaine échéance ou de réessayer après un certain délai. Vous pouvez choisir d'annuler l'exécution après un certain nombre de tentatives.

Archives

Dans la section Archives, vous pouvez définir des options telles que segmenter les archives, le taux de compression, et utiliser des méthodes d'optimisation. Les archives peuvent être segmentées et ainsi découpées en morceaux de taille fixe pour pouvoir être stockées sur plusieurs volumes (plusieurs CD par exemple). Vous utilisez une taille de segment prédéfinie ou saisissez une valeur entre 1 et 2 048 Mo (0 est équivalent à Aucune). En outre, vous pouvez compresser les archives pour sauvegarder l'espace disque bien que ceci puisse ralentir le processus de sauvegarde. Parmi les options d'optimisation, vous pouvez indiquer le taux d'entrelacement et de redondance.

Configuration

Image non disponible

Contenu de la sauvegarde

Dans cette section vous spécifiez ce que vous voulez inclure dans le backup. Les fichiers de structure et de données sont sélectionnés par défaut. Vous pouvez ajouter des fichiers ou des dossiers. Dans l'exemple ci-dessous, le dossier DocJoints est rajouté.

Emplacement des fichiers de sauvegarde

Vous pouvez choisir un dossier différent avec le bouton de navigation (…).

Informations sur la dernière sauvegarde

Vous pouvez récupérer les informations sur la dernière sauvegarde dans cette zone : la date de la dernière sauvegarde, la date de la prochaine sauvegarde, le nom de la dernière archive, le nom du fichier d'historique archivé et le statut du dernier backup.

Gestion du fichier d'historique

Dans cette section, vous pouvez choisir d'utiliser un fichier d'historique. Ce fichier contient les changements faits aux données après une sauvegarde. Des actions telles que l'ajout, la modification, et la suppression des enregistrements sont enregistrées. Les transactions sont aussi enregistrées dans ce fichier.

Différentes façons d'exécuter la sauvegarde dans 4D 2004

La sauvegarde peut être démarrée manuellement, automatiquement, ou par programmation.

Manuellement

Vous pouvez créer une sauvegarde manuellement n'importe quand en cliquant sur l'élément de sauvegarde du menu Fichier du serveur 4D ou du menu Fichier dans l'environnement Utilisateur de 4e dimension comme montré ci-dessous :

Image non disponible

Ceci affichera la fenêtre de sauvegarde :

Image non disponible


Cliquez sur le bouton Sauvegarde qui lancera une sauvegarde avec les configurations courantes des Préférences. Le bouton Préférences… ouvre les préférences de la base de données qui peuvent être changées avant de commencer la sauvegarde.

Automatiquement

Vous pouvez automatiquement exécuter la sauvegarde sans intervention de l'utilisateur en indiquant fréquence de la sauvegarde dans la page des Préférences de sauvegarde comme montré ci-dessous.

Image non disponible


Vous pouvez mettre en place une fréquence de sauvegarde toutes les heures, tous les jours, chaque semaine, certains jours, ou chaque mois. Pour désactiver ces options, vous devez sélectionner « Pas de sauvegarde automatique ». La sauvegarde sera lancée à l'heure et au jour indiqués. Comme montré dans le dialogue ci-dessus, la sauvegarde aura lieu à 2 heures du matin tous les Lundis, Mercredis et Samedis chaque semaine. Dans la section Paramètres généraux, comme vu précédemment, vous pouvez choisir de ne pas lancer de sauvegarde si aucune modification n'a été faite dans les données et ne lancer le backup qu'à la prochaine échéance.

Quand la base est créée pour la première fois, la sauvegarde automatique est choisie par défaut comme montré ci-dessous. Elle utilise les paramétrages par défaut. L'option doit être décochée avant de créer la base pour désactiver cette option :

Image non disponible

Par programmation

Vous pouvez exécuter une sauvegarde par programmation en utilisant la commande de sauvegarde. Avec les nouvelles méthodes base Sur demarrage sauvegarde et Sur arrêt sauvegarde, vous pouvez contrôler le processus de sauvegarde. Quand on exécute la commande de sauvegarde, elle utilise les configurations de sauvegarde courantes. Comme l'indique son nom, la Méthode base Sur demarrage sauvegarde est exécutée quand le processus de sauvegarde commence et la méthode base Sur arrêt sauvegarde est exécutée quand le processus de sauvegarde se termine.

Ces nouvelles méthodes de sauvegarde vous permettent de placer des conditions préalables à l'exécution d'une sauvegarde. Par exemple, vous pouvez permettre seulement à certains utilisateurs d'exécuter la sauvegarde, ou vous pouvez choisir d'annuler la sauvegarde quand une sauvegarde a été déjà faite le même jour, et même ainsi, vous pouvez contrôler la destination de la sauvegarde et alerter l'utilisateur si elle va être faite sur le même volume. Tout cela peut être fait dans la méthode base Sur demarrage sauvegarde. La valeur retournée par $0 dans cette méthode permet d'autoriser ou refuser la sauvegarde. Pour l'autoriser, $0 doit être mis à zéro. N'importe quelle autre valeur annulera la sauvegarde. La valeur passée dans $0 peut être vérifiée dans la méthode base Sur arrêt sauvegarde. De cette façon, vous pouvez personnaliser une gestion d'erreur basée sur la valeur qui est passée.

Toutes les fois que la sauvegarde se termine, la méthode base Sur arrêt sauvegarde est exécutée. Vous pouvez contrôler le statut de la sauvegarde en utilisant la commande LIRE INFORMATION SAUVEGARDE. Ou vous pouvez exécuter certaines actions basées sur la valeur retournée par la Méthode base Sur demarrage sauvegarde. Cette valeur est passée dans la variable de type Entier $1. Cette variable doit être déclarée dans la méthode.

La base de démo

Pour lancer la base exemple :
- L'Administrateur et les utilisateurs T1 et T2 n'ont pas de mot de passe
- Le mot de passe pour le Super_utilisateur est « x ».
- Sélectionnez « Lancez la sauvegarde » du menu « Sauvegarde ».

Les conditions pour que la sauvegarde se fasse sont les suivantes :
1. L'utilisateur courant doit être l'Administrateur ;
2. La précédente sauvegarde ne doit pas avoir été faite le même jour ;
3. Si le volume de destination de la sauvegarde est le même que celui de la structure, un message de confirmation est affiché, que l'utilisateur doit valider.

Si toutes ces conditions ne sont pas réunies, la sauvegarde ne se fera pas et une erreur sera affichée. Ci-dessous, voici un exemple sur la façon dont on peut contrôler la sauvegarde en utilisant par programmation les nouvelles commandes de sauvegarde. Des conditions comme montrées ci-dessous dans le code peuvent être vérifiées dans la méthode base Sur démarrage sauvegarde, quand la sauvegarde est exécutée avec la commande SAUVEGARDER. Vous pouvez passer une valeur autre que 0 au paramètre $0 pour renseigner chaque condition. Ces valeurs peuvent être vérifiées dans la méthode base Sur arrêt sauvegarde.

code exemple 4D
Sélectionnez
`Méthode base : Sur démarrage sauvegarde

`Conditions pour exécuter la sauvegarde :
```seul l'administrateur peut lancer la sauvegarde
```La sauvegarde ne sera pas exécutée si un backup a déjà été fait le même jour
```La destination de la sauvegarde est vérifiée. Si elle se fait sur le même volume que celui de la base,
````l'utilisateur est averti.
```Il peut alors choisir d'effectuer ou d'annuler la sauvegarde.

C_ENTIER(selector;$0)
C_TEXTE(Vol_Structure;Vol_BackupDestination;dest_path)

selector:=0
$0:=0

Si (Utilisateur courant="Administrateur") `la sauvegarde n'est autorisée que faite par l'Administrateur
   LIRE INFORMATION SAUVEGARDE(0;last_backupDate;last_backupTime)
   Si (last_BackupDate=Date du jour) `on ne lance la sauvegarde qu'un jour différent de la précédente
      $0:=3 `la sauvegarde a déjà été faite le même jour
   Sinon
      Vol_Structure:=ExtractVolume (Fichier structure) `on récupère le volume de la structure
      Vol_BackupDestination:=ExtractVolume (CheckDestination ) `on récupère le volume de la sauvegarde.
      Si (Vol_Structure=Vol_BackupDestination) ` si le volume de la sauvegarde est le même que
            `celui de la sauvegarde
         CONFIRMER("Êtes-vous sûr de vouloir lancer la sauvegarde sur le même volume ?";"Oui";"Non")
            ` on demande confirmation à l'utilisateur pour lancer ou pas la sauvegarde
         Si (OK#1) `si l'utilisateur ne veut pas lancer la sauvegarde
            $0:=2
         Fin de si
      Fin de si
   Fin de si
Sinon
   $0:=1 ` l'utilisateur n'est pas Administrateur
Fin de si


La valeur de la variable $0 de la méthode base Sur démarrage sauvegarde détermine si l'on autorise ou pas la sauvegarde. La sauvegarde est autorisée si $0 est égal à 0, sinon la sauvegarde est refusée. Dans la méthode ci-dessus, on vérifie d'abord l'utilisateur courant. Si l'utilisateur courant est administrateur, la date du jour est alors contrôlée avec la date de la dernière sauvegarde. Si la sauvegarde n'est pas été exécutée le même jour, le volume de sauvegarde est ensuite contrôlé avec l'emplacement actuel du fichier de structure. Si l'emplacement est sur un volume différent, la sauvegarde est exécutée. Autrement, un message est affiché alertant l'utilisateur et l'incitant à confirmer. La valeur assignée à $0 dépend des conditions rencontrées.

La valeur retournée dans le $0 de la méthode base Sur démarrage sauvegarde peut être donc vérifiée dans le $1 par la méthode base Sur arrêt sauvegarde. La variable $1 contiendra la valeur retournée par la méthode base Sur démarrage sauvegarde. Vous pouvez personnaliser le message de l'erreur renvoyée par ce paramètre. Vous pouvez utiliser la commande LIRE INFORMATION SAUVEGARDE pour vérifier l'erreur intervenue sur la sauvegarde. Comme le montre le code ci-dessous, si une des conditions à la sauvegarde est fausse, la sauvegarde ne se fait pas et le message d'erreur est affiché. Si l'erreur n'est pas relative aux conditions premières, un numéro d'erreur est renvoyé, avec sa description.

code exemple 4D
Sélectionnez
`Méthode base : Sur arrêt sauvegarde

C_ENTIER(error_num;$1)
C_TEXTE(error_desc)

Au cas ou
   : ($1=1)
      ALERTE("La sauvegarde n'a pas été effectuée, car l'Utilisateur courant n'est pas"+
                              " Administrateur.")
   : ($1=2)
      ALERTE("La sauvegarde n'a pas été effectuée, car vous avez choisi de ne pas la faire sur"+
                              " le même volume que votre base de données.")
   : ($1=3)
      ALERTE("La sauvegarde n'a pas été effectuée, car une précédente sauvegarde a été faite"+
                              " aujourd'hui.")
   : ($1=0)
      ALERTE("La sauvegarde s'est déroulée avec succès !")

   Sinon
      LIRE INFORMATION SAUVEGARDE(2;error_num;error_desc)
      ALERTE("Erreur : "+Chaine(error_num)+" - "+error_desc)

Fin de cas


Les configurations de la sauvegarde sont archivées dans un fichier XML (backup.xml). Les informations affichées dans les préférences sont, pour la plupart, prises dans ce fichier XML. Vous pouvez alors par programmation indiquer ou récupérer les configurations de sauvegarde en utilisant des commandes XML de 4D.

Dans la méthode base Sur démarrage sauvegarde, une méthode projet appelée CheckDestination récupère le chemin d'accès du dossier de destination à partir du fichier « Backup.xml ». Le code de cette méthode est donné ci-dessous. Dans la méthode, le fichier Backup.xml est d'abord analysé. Puis, l'élément <DestinationFolder> est localisé et sa valeur est retournée par la méthode :

code exemple 4D
Sélectionnez
   `Methode projet : CheckDestination

   `Description: renvoie le nom du dossier de destination de la sauvegarde (stocké dans le fichier Backup.xml).

C_TEXTE(Path_Structure;$0)
C_TEXTE(Path_Prefs;Path_Structure;Path_BackupXML)
C_TEXTE($elementRef1;$elementRef2)
C_ENTIER($separator;$StrPtr)
C_ENTIER($myPlatform;$mySystem;$myMachine)

PROPRIETES PLATE FORME($myPlatform;$mySystem;$myMachine)

Si ($myPlatform=Windows ) ` on vérifie la plateforme
   $separator:=Code ascii("\\")
Sinon
   $separator:=Code ascii(":")
Fin de si

Path_Structure:=Fichier structure ` chemin d'accès de la structure.
$StrPtr:=Longueur(Path_Structure) ` longueur du chemin d'accès

Tant que (Path_Structure[[$StrPtr]]#Caractere($separator))
      ` on part de la fin de la chaîne jusqu'à trouver le séparateur
   $StrPtr:=$StrPtr-1
Fin tant que

   ` on contruit le chemin d'accès au dossier "Preferences" qui contient le fichier "Backup.xml"
$var1:=Sous chaine(Path_Structure;1;$StrPtr) 
Path_Prefs:=$var1+"Preferences"
Path_BackupXML:=Path_Prefs+Caractere($separator)+"Backup"+Caractere($separator)+"Backup.xml"

   `Dans ce fichier, nous récupérons le volume de destination de la sauvegarde
$ref1:=DOM Analyser source XML(Path_BackupXML) 
$elementRef1:=DOM Chercher element XML($ref1;"/Preferences4D/Backup/Settings/General")

   ` on cherche l'élément Destination folder
$elementRef2:=DOM Chercher element XML($elementRef1;"/General/DestinationFolder")

DOM LIRE VALEUR ELEMENT XML($elementRef2;value) ` on récupère la valeur

DOM FERMER XML($ref1)

$0:=value ` on renvoie dans $0 le nom du dossier de destination.

Note
Avec 4D Server, quand on exécute une commande de sauvegarde sur le Client, la sauvegarde est considérée comme une procédure stockée et est exécutée sur le serveur.

L'utilisation d'un fichier d'historique

La restauration du dernier fichier de sauvegarde peut ne pas être suffisante pour restaurer la base de données à son état le plus récent. Des changements sur les données ont pu être faits après la sauvegarde. En outre, 4D stocke temporairement les enregistrements dans un cache avant de les stocker sur le disque pour optimiser les performances de l'application. Cependant, quand un incident se produit, ces informations ne sont pas encore sauvegardées de manière permanente sur le disque et peuvent être perdues. C'est dans ce contexte que le fichier d'historique entre en jeu.

Tous les changements faits sur les données comme les modifications, ajouts, et suppressions, incluant les transactions, sont enregistrés dans ce fichier d'historique. Tandis que des changements d'enregistrement sont sauvegardés dans le cache ou sauvés sur le disque, le fichier d'historique enregistre également ces changements chronologiquement. Il contiendra toutes ces informations à partir de la dernière sauvegarde exécutée sur la base de données. Chaque fois qu'une sauvegarde est exécutée, le fichier d'historique est archivé et remis à l'état initial.

En utilisant un fichier d'historique, vous pouvez restaurer une sauvegarde précédente et intégrer les changements qui ont été faits après la dernière sauvegarde. Ceci met la base de données à jour après un incident. D'ailleurs si un incident se produit avant que des changements contenus dans le cache de données soient stockés, cette information est stockée dans le fichier d'historique et les opérations manquantes sont automatiquement réintégrées à l'ouverture suivante de la base de données (si cette option a été choisie dans les Préférences de sauvegarde).

Pour créer un fichier d'historique, une sauvegarde doit d'abord avoir été faite. Vous pouvez alors mettre en place l'option « Utiliser le fichier d'historique » dans la section « Gestion du fichier d'historique » (Configuration). Cette option est choisie par défaut quand une base de données est créée. Vous pouvez arrêter l'utilisation d'un fichier d'historique à n'importe quel moment en décochant cette option.

Vous pouvez vérifier le contenu de ce fichier d'historique en sélectionnant la ligne « Vérifier fichier d'historique… » dans le Menu Fichier du Mode Utilisation. Un dialogue s'affiche :

Image non disponible

Restauration

En cas d'incidents tels que la perte de données, ou de pannes de courant, vous pouvez restaurer votre sauvegarde manuellement ou automatiquement. Le fichier d'historique peut être intégré manuellement ou automatiquement avec la dernière sauvegarde.

Restauration manuelle

Vous pouvez restaurer une sauvegarde manuellement en utilisant la section « Restituer une base » du dialogue d'ouverture de 4D ou 4D Server. Vous pouvez aussi le faire par programmation avec la commande RESTITUER.

Image non disponible


Vous pouvez y sélectionner une archive « BaseDeDonnées[xxx].4BK » ou un fichier d'historique « BaseDeDonnées[xxx].4BL ». Le chemin d'accès au fichier de sauvegarde et son contenu sont affichés dans la partie droite de la page de restitution. Pour sélectionner un fichier d'historique ou une archive de ce fichier, vous devez les localiser en utilisant le bouton « Ouvrir… ». Lorsque vous cliquez sur le bouton « Restituer… », le dialogue de restauration, comme ci-dessous, est affiché. Vous pouvez modifier le dossier de destination des fichiers restitués et commencer la restitution en cliquant sur le bouton Restituer.

Image non disponible

Note
L'archive de sauvegarde est nommée « BaseDeDonnées[xxx].4BK » (ou n'importe quel nom que vous lui donneriez) et l'archive du fichier d'historique est appelé « BaseDeDonnées[xxx-1].4BL ». Par exemple si vous avez une base de données nommée DB1, le fichier de sauvegarde se nommera DB1[0001].4BK par défaut et l'archive du fichier d'historique sera nommée DB1[0000].4BL. L'archive du fichier d'historique attachée à une sauvegarde porte toujours le numéro de la sauvegarde -1.

Après restitution de la base, un fichier d'historique peut être manuellement intégrée pour récupérer les modifications faites aux données depuis la dernière sauvegarde. Le fichier d'historique doit correspondre à l'archive de sauvegarde pour être lié à elle. Quand la sauvegarde est faite, le fichier courant d'historique est aussi archivé et il est vidé. Chaque changement fait aux données sera stocké dans le nouveau fichier d'historique courant. L'archive du précédent fichier d'historique peut être utilisée pour relier une sauvegarde faite précédemment, avec la dernière sauvegarde. Ci-dessous voici quelques scénarios pour illustrer cela :

Scénario 1

La sauvegarde est exécutée chaque jour. Mercredi, la base « crashe » et pour restaurer une sauvegarde faite le mardi et la mettre à jour, les différentes étapes sont les suivantes :

1 - La sauvegarde du mardi est restaurée ;

2 - Lorsque la base restaurée est lancée, un dialogue est affiché :

Image non disponible


3 - Quand le bouton OK est cliqué, il propose un dialogue d'ouverture permettant de choisir le fichier d'historique courant et de l'intégrer. Ceci permettra de récupérer tous les changements fait entre la dernière sauvegarde et avant que la base « plante ».

Scénario 2

Si vous voulez restaurer une sauvegarde créée à une date antérieure, une restauration séquentielle sera créée. Par exemple, comme dans le scénario 1 où une sauvegarde est effectuée chaque jour, pour restaurer une sauvegarde faite le lundi et intégrer les changements des données intervenus avant que la base crasche le mercredi, les différentes étapes sont les suivantes :

1 - Restauration de l'archive du lundi ;

2 - Restauration de l'archive du fichier d'historique faite le mardi ;

3 - Ouverture de la base restaurée et sélection du fichier d'historique. Ceci devrait intégrer les changements de données avant la sauvegarde faite le mardi ;

4 - Dans la page de configuration du backup, des Préférences de la base, décochez l'utilisation du fichier d'historique ;

5 - Cochez à nouveau l'utilisation du fichier d'historique et sélectionnez le fichier d'historique courant qui était utilisé avant que la base crashe le mercredi.
Cela devrait intégrer les changements effectués dans la base entre la sauvegarde du mardi et avant que la base crasche. (Si on ne peut pas accéder aux Préférences de base, vous pouvez déplacer le fichier d'historique utilisé par la base restaurée à un endroit différent. À l'ouverture, il vous sera demandé de sélectionner un fichier d'historique. Vous pouvez alors choisir le fichier à intégrer pour avoir les changements les plus récents).

Restauration automatique

Vous pouvez restaurer automatiquement une sauvegarde quand un incident se produit sur la base, en choisissant les options de restauration dans la section correspondante :

Image non disponible


« Intégrer le dernier historique si la base est incomplète » et « Lancer la base après la restitution automatique » sont des options sélectionnées par défaut. Vous pouvez choisir de repartir de la dernière sauvegarde si la base est endommagée.

Si l'option « Restituer la dernière sauvegarde si la base est endommagée » est sélectionnée, une restitution de la dernière sauvegarde est lancée automatiquement si un problème survient au lancement de la base. Et quand l'option « Lancer la base après la restitution automatique » est cochée, la base restaurée est automatiquement relancée. Ceci ne nécessite aucune intervention de l'utilisateur.

De plus, avec l'option « Intégrer le dernier historique si la base est incomplète » est sélectionnée, le fichier d'historique courant est automatiquement intégré quand la base est restaurée. Les opérations de sauvegarde sont stockées dans le « Journal des sauvegardes.txt » qui est habituellement au même niveau que la Structure.

Résumé

4D 2004 possède un module de sauvegarde intégré.

La sauvegarde et la restitution peuvent être faites par 4D automatiquement, manuellement ou par programmation.

Chaque sauvegarde utilise les paramétrages de sauvegarde indiqués dans les Préférences de la base. Le calendrier des sauvegardes et les options automatiques de restitution vous permettent de sauvegarder et restaurer automatiquement.

La sauvegarde peut être faite en mode utilisation, Menu Fichier. Vous pouvez aussi la faire par programmation. Les modifications faites aux données, transactions incluses, sont chronologiquement stockées dans un fichier d'historique. Ceci permet d'intégrer les modifications dans votre base en cas d'incident.

Tout en un, les fonctionnalités du module de sauvegarde en 4D 2004 simplifient les opérations de sauvegarde et de restitution de votre base.

Base exemple

Télécharger la base exemple.

Vous avez aimé ce tutoriel ? Alors partagez-le en cliquant sur les boutons suivants : Viadeo Twitter Facebook Share on Google+   

Ce document est issu de https://www.developpez.com et reste la propriété exclusive de son auteur. La copie, modification et/ou distribution par quelque moyen que ce soit est soumise à l'obtention préalable de l'autorisation de l'auteur.