PICTURE LIBRARY LIST

Version 6.0.2

PICTURE LIBRARY LIST (BildRefs; BildNamen)

Der Befehl PICTURE LIBRARY LIST gibt die Referenznummern und -namen der Bilder zurück, die in der Bildbibliothek der Datenbank gespeichert sind.

Nach dem Aufruf finden Sie die Referenznummer im Array BildRefs, die Namen im Array BildNamen. Beide Arrays sind synchronisiert: Das n-te Element von BildRefs entspricht dem n-ten Element von BildNamen.

BildRefs kann ein Array vom Typ Zahl, Lange Ganzzahl oder Ganzzahl sein. Wird das Array im interpretierten Modus nicht vor Aufrufen von PICTURE LIBRARY LIST definiert, ist es standardmäßig vom Typ Lange Ganzzahl.

BildNamen kann ein Array vom Typ alphanumerisch oder Text sein. Wird das Array im interpretierten Modus nicht vor Aufrufen von PICTURE LIBRARY LIST definiert, ist es standardmäßig vom Typ Text.

Die Bildnamen in der Bildbibliothek können maximal 31 Zeichen lang sein. Verwenden Sie als BildNamen ein Array vom Typ alpahnumerisch, geben Sie eine ausreichende Länge an, damit der Name nicht abgeschnitten wird.

Gibt es keine Bilder in der Bildbibliothek, erhalten Sie leere Arrays.

Mit der Funktion Size of array command erhalten Sie die Größe eines der Arrays und können so feststellen, wieviel Bilder in der Bildbibliothek gespeichert sind.

1. Folgender Code gibt den Katalog der Bildbibliothek in den Arrays alPicRef und asPicName zurück:

   PICTURE LIBRARY LIST(alPicRef;asPicName)

2. Folgendes Beispiel prüft, ob die Bildbibliothek leer ist oder nicht:

   PICTURE LIBRARY LIST(alPicRef;asPicName)
   If (Size of array(alPicRef)=0)
      ALERT("Die Bildbibliothek ist leer.")
   Else
      ALERT("Die Bildbibliothek enthält "+String(Size of array(alPicRef))+" Bilder.")
   End if

3. Folgendes Beispiel exportiert die Bildbibliothek in ein Dokument auf der Festplatte:

   PICTURE LIBRARY LIST($alPicRef;$asPicName)
   $vlNbPictures:=Size of array($alPicRef)
   If ($vlNbPictures>0)
      SET CHANNEL(12;"")
      If (OK=1)
         $vsTag:="4DV6PICTURELIBRARYEXPORT"
         SEND VARIABLE($vsTag)
         SEND VARIABLE($vlNbPictures)
         gError:=0
         For($vlPicture;1;$vlNbPictures)
            $vlPicRef:=$alPicRef{$vlPicture}
            $vsPicName:=$asPicName{$vlPicture}
            GET PICTURE FROM LIBRARY($alPicRef{$vlPicture};$vgPicture)
            If (OK=1)
               SEND VARIABLE($vlPicRef)
               SEND VARIABLE($vsPicName)
               SEND VARIABLE($vgPicture)
            Else
               $vlPicture:=$vlNbPictures+1
               gError:=-108
            End if
         End for
         SET CHANNEL(11)
         If (gError#0)
            ALERT(" Bildbibliothek wurde nicht exportiert, mehr Speicher zuweisen.")
            DELETE DOCUMENT (Document)
         End if
      End if
   Else
      ALERT("Die Bildbibliothek ist leer.")
   End if

GET PICTURE FROM LIBRARY, REMOVE PICTURE FROM LIBRARY, SET PICTURE TO LIBRARY.