ARRAY TO STRING LIST

Version 6.0

ARRAY TO STRING LIST (Strings; ResNR{; ResDatei})

Der Befehl ARRAY TO STRING LIST erstellt oder schreibt die Stringlisten-Ressource ("STR#") mit der Kennummer ResNR neu. Der Inhalt der Ressource wird aus den Strings erstellt, die im Array Strings übergeben wurden. Das Array kann vom Typ String oder Text sein.

Kann die Ressource nicht hinzugefügt werden, wird die OK Variable auf 0 (Null) gesetzt.

Übergeben Sie in ResDatei eine gültige Referenznummer für die Ressourcendatei, wird die Ressource dieser Datei hinzugefügt. Übergeben Sie ResDatei nicht, wird die Ressource in der obersten Ressourcendatei in der Kette der Ressourcendateien hinzugefügt. Das ist die zuletzt geöffnete Ressourcendatei.

Hinweis: Jeder String einer Stringlisten-Ressource kann bis zu 255 Zeichen enthalten.

Tipp: Begrenzen Sie Ihre Stringlisten-Ressource auf die Größe 32K und auf ein paar hundert Strings pro Ressource.

Ihre Datenbank enthält einen bestimmten Schriftensatz.

In der Datenbankmethode On Exit schreiben Sie:

      ` Datenbankmethode On Exit 
   If (<>vbFontsAreOK)
      FONT LIST($atFont)
      $vhResFile:=Open resource file("Schriftensatz")
      If (OK=1)
         ARRAY TO STRING LIST($atFont;15000;$vhResFile)
         CLOSE RESOURCE FILE($vhResFile)
      End if
   End if

In der Datenbankmethode On Startup schreiben Sie:

      ` Datenbankmethode On Startup
   <>vbFontsAreOK:=False
   FONT LIST($atNewFont)
   If (Test path name("FontSet")#Is a document)
      $vhResFile:=Create resource file("Schriftensatz")
   Else
      $vhResFile:=Open resource file("Schriftensatz")
   End if
   If (OK=1)
      STRING LIST TO ARRAY(15000;$atOldFont;$vhResFile)
      If (OK=1)
         <>vbFontsAreOK:=True
         For($vlElem;1;Size of array($atNewFont))
            If ($atNewFont{$vlElem}#$atOldFont{$vlElem}))
               $vlElem:=MAXLONG
               <>vbFontsAreOK:=False
            End if
         End for
      Else
         <>vbFontsAreOK:=True
      End if
      CLOSE RESOURCE FILE($vhResFile)
   End if
   If(Not(<>vbFontsAreOK))
      CONFIRM("Sie verwenden nicht den gleichen Schriftensatz, OK?")
      If(OK=1)
         <>vbFontsAreOK:=True
      Else
         QUIT 4D
      End if
   End if

SET STRING RESOURCE, SET TEXT RESOURCE, STRING LIST TO ARRAY.

Wurde die Ressource geschrieben, wird OK auf 1 gesetzt, sonst auf 0 (Null).