PV SELECT RANGE

Version 2004.4 (Geändert)

PV SELECT RANGE (Bereich; Links; Oben; Rechts; Unten; Aktion)

Der Befehl PV SELECT RANGE wählt den Zellenbereich, definiert durch die Parameter Links, Oben, Rechts und Unten.

Mit dem Parameter Aktion definieren Sie den Auswahlvorgang, wenn bereits eine Zellenauswahl existiert: Sie können den Zellenbereich der Auswahl hinzufügen, die Auswahl auf den Zellenbereich reduzieren oder den Bereich aus der Auswahl entfernen.

Den Parameter Aktion definieren Sie mit einer Konstanten unter dem Thema PV Aktion Auswahl.

1. Wir wollen den Zellenbereich E2, E3, F2, F3 auswählen. Die Wahl hängt ab vom Kontext, d.h. von den bereits gewählten Zellen:

      `Arrays, welche die vorhandene Auswahl definieren:
   ARRAY LONGINT($Left;0)  `Spaltennummern der linksbündigen Zellen
   ARRAY LONGINT($Top;0)  `Zeilennummern der oberen Zellen
   ARRAY LONGINT($Right;0)  `Spaltennummern der rechtsbündigen Zellen
   ARRAY LONGINT($Bottom;0)  `Zeilennummern der unteren Zellen

   PV GET SELECTED RANGES LIST (Bereich;$Left;$Top;$Right;$Bottom)  
                           `Erhalte gewählte Bereiche, sofern vorhanden

   If (Size of array($Left)=0)  `Keine aktuelle Auswahl
     PV SELECT RANGE (Bereich;5;2;6;3;pv selection set )  
                           `Setze den Bereich als die aktuelle Auswahl
   Else   
     PV SELECT RANGE (Bereich;5;2;6;3;pv selection add )  
                           `Füge Bereich zur aktuellen Auswahl hinzu
   End if 

2. Dieses Beispiel wählt die Zelle aus bzw. ab, in die der Benutzer mit gedrückter Strg-Taste unter Windows oder Wahltaste auf Mac OS geklickt hat, je nachdem, ob sie zur Auswahl gehört oder nicht.

      `Definition des Bereichs aktuelle Auswahl
   PV SELECT RANGE (Bereich;1;5;2;9;pv selection set)

      `Bei Klick in den Bereich Methode aufrufen
   PV ON EVENT(Bereich;pv on clicked;"BeispielView")

      `Methode BeispielView
   C_LONGINT($1;$2;$3;$4;$5)
   If (($2=pv on clicked) & ($3=2048)) `Strg+Klick oder Wahltaste+Klick
      If (PV Is cell selected (Bereich;$4;$5)=1)
         `Gehört die Zelle zur Auswahl, wird sie entfernt.
         PV SELECT RANGE (Bereich;$4;$5;$4;$5;pv selection reduce)
      Else 
         `Gehört die Zelle nicht zur Auswahl, wird sie hinzugefügt.
         PV SELECT RANGE (Bereich;$4;$5;$4;$5;pv selection add)
      End if
   End if

PV GET CURRENT CELL, PV Is range selected.

Thema PV Aktion Auswahl.