Restaurer les images de la bibliothèque

Thomas Schlumberger

- Titre : Restaurer les images de la bibliothèque

- Auteur : Thomas Schlumberger

- Parution : 9 octobre 2008

- Licence : Copyright ® 2008 4D s.a.. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.

Sommaire

Produit : 4D v2004, v11 SQL  ·  Plateforme : Mac & Windows ♪

Vous avez des images de votre bibliothèque d'images qui sont corrompues et impossible de les supprimer.

Voici une méthode qui permet de récupérer dans des tableaux les images de la bibliothèque, et de les rétablir (après correction individuelle éventuelle).

code 4D

` Méthode pour récupérer chaque image de la bibliothèque d'images, les effacer et les réécrire

C_ENTIER LONG($i;$vlNb_Images)
TABLEAU ENTIER LONG(t_ImageRefs;0)
TABLEAU TEXTE(t_NomImages;0)
LISTE IMAGES DANS BIBLIOTHEQUE(t_ImageRefs;t_NomImages)
$vlNb_Images:=Taille tableau(t_ImageRefs)
TABLEAU IMAGE(t_Mes_Images;$vlNb_Images)

` Récupérer les images de la bibliothèque d'images
Boucle($i;1;$vlNb_Images)
LIRE IMAGE DANS BIBLIOTHEQUE(t_ImageRefs{$i};t_Mes_Images{$i})
Fin de boucle

` ---- sauvegarder les trois tableaux ---
`(soit dans une table, soit dans des fichiers) ---
` ---- si vous devez corriger les images, compléter votre code ici ----

` Supprimer les images de la bibliothèque d'images
CONFIRMER("Voulez-vous vraiment supprimer les images de la bibliothèque d'images ?")
Si(OK=1)
Boucle($i;1;$vlNb_Images) ` ou seulement une sélection d'images plus restreinte.
SUPPRIMER IMAGE DANS BIBLIOTHEQUE(t_ImageRefs{$i})
Fin de boucle
Fin de si

` Rétablir les images (après correction ?) dans la bibliothèque d'images,
` après mise à jour des tableaux.
CONFIRMER("Voulez-vous vraiment ajouter/remplacer les images de la bibliothèque d'images ?")
Si(OK=1)
Boucle($i;1;$vlNb_Images) ` ou seulement une sélection d'images plus restreinte.
ECRIRE IMAGE DANS BIBLIOTHEQUE(t_Mes_Images{$i};t_ImageRefs{$i};t_NomImages{$i})
Fin de boucle
Fin de si

Vous pouvez déjà exécuter cette méthode directement, en validant les demandes de confirmation (sur une copie de votre structure) et s'il n'y a pas d'erreur d'accès, voir si cela corrige vos images.

Sinon, il faudra sauvegarder le contenu des trois tableaux, éditer chaque image, et si possible les corriger, avant de les remettre dans le tableau t_Mes_Images pour les écrire à nouveau dans la Bibliothèque d'images.