Rendre sélectionnables les anciens fichiers d'états rapides

| 4D Quality & Assurance | Support Technique 4D |

- Titre : Rendre sélectionnables les anciens fichiers d'états rapides

- Auteurs : 4D Quality & Assurance, Support Technique 4D

- Parution : 27 juin 2007

- Licence : Copyright ® 2007 4D s.a. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.

Sommaire

Produit : 4D 2004 · Plateforme : Mac & Win ♪

Vous avez un dossier avec une centaine de fichiers d'états rapides qui ont été créés par 4D de version en version. Dans le dialogue d'ouverture de fichier, 4D ne reconnaît pas et donc n'affiche pas ces états rapides.

La solution est de les renommer avec l'extension ".4QR" pour leur assigner le bon type de document.

Ceci peut-être fait de manière automatisée pour tous les documents Quick Report, sans avoir besoin de les renommer manuellement.

La méthode ci-dessous crée un nouveau dossier, y copie les documents et les renomme avec l'extension adéquate.

` ----------------------------------------------------
` User name (OS): Stirtiat
` Date and time: 27/06/07, 17:44:22
` ----------------------------------------------------
` Method: COPY_NQR
` ----------------------------------------------------

`Déclaration des variables
TABLEAU TEXTE(tDocuments;0)
C_ENTIER LONG($i)
C_HEURE($id)
C_TEXTE($Extension4QR)
C_TEXTE($DossierEtatsACopier;$DossierEtatsRenommes)

`Définition du séparateur pour les chemins d'accès selon la plateforme
`(fait généralement l'objet d'une méthode à part)
C_ENTIER LONG(<>plateforme;<>systeme;<>machine;<>langue)
C_ALPHA(2;<>sep)
PROPRIETES PLATE FORME(<>plateforme;<>systeme;<>machine;<>langue)
Si (<>plateforme=Windows )
<>sep:="\\"
Sinon
<>sep:=":"
Fin de si

`Définition du chemin vers le dossier de la base
`(fait généralement l'objet d'une méthode à part)
C_TEXTE(<>FichierStructure;<>DossierStructure)
<>FichierStructure:=""
<>DossierStructure:=""
C_ENTIER LONG($Pos)
<>FichierStructure:=Fichier structure
$Pos:=Position(<>sep;<>FichierStructure)
Tant que ($Pos>0)
<>DossierStructure:=<>DossierStructure+Sous chaine(<>FichierStructure;1;$Pos)
<>FichierStructure:=Sous chaine(<>FichierStructure;$Pos+1)
$Pos:=Position(<>sep;<>FichierStructure)
Fin tant que

`--- COPIE DES DOCUMENTS ---

`Init noms des dossiers
$DossierEtatsACopier:="Etats"
$DossierEtatsRenommes:="Etats_NQR"

`Vérification de l'existence du dossier "Etats_NQR", sinon le créer
Si (Tester chemin acces($DossierEtatsRenommes)#Est un répertoire )
CREER DOSSIER($DossierEtatsRenommes)
Fin de si

LISTE DES DOCUMENTS($DossierEtatsACopier;tDocuments)
Boucle ($i;1;Taille tableau(tDocuments))
`Copier les documents du dossier "Etats" vers le dossier définitif avec renommage en .4QR
$Extension4QR:=".4QR"
$NouveauNom4QR:=<>DossierStructure+$DossierEtatsRenommes+<>sep+tDocuments{$i}+$Extension4QR
COPIER DOCUMENT(<>DossierStructure+$DossierEtatsACopier+<>sep+tDocuments{$i};$NouveauNom4QR)
Fin de boucle

`Fin de méthode

Documentation des commandes :

- CREER DOSSIER

- LISTE DES DOCUMENTS

- COPIER DOCUMENT