Developpez.com

Une très vaste base de connaissances en informatique avec
plus de 100 FAQ et 10 000 réponses à vos questions

Developpez.com - 4D
X

Choisissez d'abord la catégorieensuite la rubrique :


4D for OCI et les colonnes de type date

Date de publication : 23/05/05

Par Stéphanie Tirtiat (Intl Tech Support)
 



Produit : 4D OCI 2004 · Plateforme : Mac & Win


Si vous avez des difficultés à retourner les valeurs des colonnes Oracle de type date avec 4D for OCI, utilisez SQLT_ODT au lieu de SQLT_DATE :


      ` ---------- exemple ----------

   TABLEAU DATE(results;3)
   TABLEAU ENTIER LONG($tNull;1)
   TABLEAU ENTIER LONG($tTailles;1)
   TABLEAU ENTIER LONG($tCodes;1)

   $tTailles{1}:=255

   $UserName:="xxx"
   $Password:="xxx"
   $OraServ:="xxx"

   $sql:="SELECT date_fact FROM factures"

   $Status:=OCIEnvCreate ($DescrEnv;OCI_DEFAULT)
   $Status:=OCIHandleAlloc ($DescrEnv;$DescrErr;OCI_HTYPE_ERROR)
   $Status:=OCIHandleAlloc ($DescrEnv;$DescrService;OCI_HTYPE_SVCCTX)
   $Status:=OCIHandleAlloc ($DescrEnv;$DescrAuth;OCI_HTYPE_SESSION)
   $Status:=OCIHandleAlloc ($DescrEnv;$DescrServer;OCI_HTYPE_SERVER)

   $Status:=OCIServerAttach ($DescrServer;$DescrErr;$OraServ)
   $Status:=OCIAttrSetVal ($DescrService;$DescrServer;OCI_ATTR_SERVER;$DescrErr)
   $Status:=OCIAttrSetText ($DescrAuth;$UserName;OCI_ATTR_USERNAME;$DescrErr)
   $Status:=OCIAttrSetText ($DescrAuth;$Password;OCI_ATTR_PASSWORD;$DescrErr)
   $Status:=OCISessionBegin ($DescrService;$DescrErr;$DescrAuth;OCI_CRED_RDBMS;OCI_DEFAULT)
   $Status:=OCIAttrSetVal ($DescrService;$DescrAuth;OCI_ATTR_SESSION;$DescrErr)

   $Status:=OCIHandleAlloc ($DescrEnv;$DescrStmt;OCI_HTYPE_STMT)
   $Status:=OCIStmtPrepare ($DescrStmt;$DescrErr;$sql;Length($sql))

      `$sqlt:=SQLT_DATE
   $sqlt:=SQLT_ODT
   $Status:=OCIDefineByPos ($DescrStmt;$DescrDefine;$DescrErr;1;->results;$sqlt;
                                      ->$tNull;->$tTailles;->$tCodes;OCI_DEFAULT)

   $Status:=OCIStmtExecute ($DescrService;$DescrStmt;$DescrErr;0;0;0;0;OCI_DEFAULT)

   $Status:=OCIStmtFetch ($DescrStmt;$DescrErr;10)

   $text:=Chaine(results{1})+Caractere(13)
   Boucle ($i;2;Taille tableau(results))
      $text:=$text+Chaine(results{$i})+Caractere(13)
   Fin de boucle

   ALERTE("TABLEAU DATE :"+Caractere(13)+$text)

   $Status:=OCISessionEnd ($DescrService;$DescrErr;$DescrAuth)
   $Status:=OCIServerDetach ($DescrServer;$DescrErr)
   $Status:=OCIHandleFree ($DescrService)
   $Status:=OCIHandleFree ($DescrServer)
   $Status:=OCIHandleFree ($DescrErr)
   $Status:=OCIHandleFree ($DescrEnv)

   TABLEAU DATE(results;0)

      ` ---------- fin exemple ----------


En complément, petit script SQL pour créer la table factures :

drop table factures;
create table factures (ID_fact varchar(3), date_fact date);
insert into factures (ID_fact,date_fact) values ('F01','10/05/2005');
insert into factures (ID_fact,date_fact) values ('F02','11/05/2005');
insert into factures (ID_fact,date_fact) values ('F03','12/05/2005');
select * from factures;
commit;



Valid XHTML 1.1!Valid CSS!

Copyright © 2005 4D s.a. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.

Contacter le responsable de la rubrique 4D