4D For OCI et la lecture des métadonnées

`SELECT table_name FROM user_tables

OCI_SELECT_OBJECT (->tt_Tables;"table_name";"user_tables")

`SELECT view_name FROM user_views

OCI_SELECT_OBJECT (->tt_Views;"view_name";"user_views")

`SELECT DISTINCT name FROM user_source WHERE Type='PROCEDURE'

OCI_SELECT_OBJECT (->tt_Procedures;"distinct name";"user_source";"WHERE Type='PROCEDURE'")

`SELECT distinct name FROM user_source WHERE Type='FUNCTION'

OCI_SELECT_OBJECT (->tt_Functions;"distinct name";"user_source";"WHERE Type='FUNCTION'")

`SELECT object_name FROM user_objects WHERE object_type='PACKAGE'

OCI_SELECT_OBJECT (->tt_Packages;"object_name";"user_objects";"WHERE object_type='PACKAGE'")

`OCI_DESCRIBE_TABLE_OR_VIEW

C_TEXTE($1) `nom de la table ou de la vue à décrire
C_ENTIER LONG($2) `1 (OCI_PTYPE_TABLE) : description de la table
`2 (OCI_PTYPE_VIEW) : description de la vue:
C_POINTEUR(${3}) `pointeurs sur les tableaux des noms et types de colonnes
C_ENTIER LONG($status) `code retour de la fonction OCI
C_ENTIER LONG($dschp) `handle descripteur
C_ENTIER LONG($collsth) `handle pour la liste des colonnes
C_ENTIER LONG($colh) `handle colonne
C_ENTIER LONG($paramh) `handle paramètre
C_ENTIER LONG($index;$nb_columns) `nombre de colonnes
C_TEXTE($name_column) `nom d'une colonne
C_ENTIER LONG($dtype_column) `code du type de donnée d'une colonne
C_TEXTE($lib_dtype_column) `libellé du type de donnée de la colonne

`allocation du handle descripteur
$status:=OCIHandleAlloc (envhp;$dschp;OCI_HTYPE_DESCRIBE)
`1 : OCI_PTYPE_TABLE (pour une table), 2 : OCI_PTYPE_VIEW (pour une vue)
$status:=OCIDescribeAnyText (svchp;errhp;$1;1;OCI_DEFAULT;$2;$dschp)
`récupération du `handle paramètre $paramh, attribut du handle descripteur $dschp
$status:=OCIAttrGetVal ($dschp;$paramh;OCI_ATTR_PARAM;errhp)
`récupération du nombre de colonnes de la table
$status:=OCIAttrGetVal ($paramh;$nb_columns;OCI_ATTR_NUM_COLS;errhp)
`récupération du handle liste des colonnes $collsth
$status:=OCIAttrGetVal ($paramh;$collsth;OCI_ATTR_LIST_COLUMNS;errhp)

Si ($nb_columns>0)
   `boucle sur les colonnes
   Boucle ($index;1;$nb_columns)
      `récupération du handle colonne $colh
      $status:=OCIParamGet ($collsth;errhp;$colh;$index)
      `nom de la colonne
      $status:=OCIAttrGetText($colh;$name_column;OCI_ATTR_NAME;errhp)
      `type de la colonne
      $status:=OCIAttrGetVal($colh;$dtype_column;OCI_ATTR_DATA_TYPE;errhp)  
      `récupération du libellé du type de donnée de la colonne avec le code du type
      $lib_dtype_column:=OCI_Lib_External_Type($dtype_column)  
      `inscrire le nom de la colonne
      AJOUTER A TABLEAU($3->;$name_column)
      `inscrire le libellé du type de la colonne
      AJOUTER A TABLEAU($4->;$lib_dtype_column)  
   Fin de boucle
Fin de si

`OCI_DESCRIBE_SUBPROGRAM

C_TEXTE($1) `nom du sous-programme (procédure ou fonction) à décrire
C_ENTIER LONG($2) `Description d'une procédure ou d'une fonction ?
`3 : OCI_PTYPE_PROC, 4 : OCI_PTYPE_FUNC
C_POINTEUR(${3})  `listes des paramètres de la procédure et leurs types
C_ENTIER LONG($status)  `code retour de la fonction OCI
C_ENTIER LONG($count;$startloop;$endloop)
C_ENTIER LONG($dschp)  `handle descripteur
C_ENTIER LONG($paramh)  `handle paramètre
C_ENTIER LONG($args_listh)  `handle sur la liste des paramètres du sous-programme
C_ENTIER LONG($argh)  `handle sur un paramètre du sous-programme
C_ENTIER LONG($args_num)  `nombre de paramètres du sous-programme
C_ENTIER LONG($arg_type)  `type du paramètre du sous-programme
C_TEXTE($arg_name)  `nom du paramètre du sous-programme

$status:=OCIHandleAlloc (envhp;$dschp;OCI_HTYPE_DESCRIBE)
$status:=OCIDescribeAnyText (svchp;errhp;$1;1;OCI_DEFAULT;$2;$dschp)
`$2=3 :OCI_PTYPE_PROC, $2=4 : OCI_PTYPE_FUNC
$status:=OCIAttrGetVal ($dschp;$paramh;OCI_ATTR_PARAM;errhp)
$status:=OCIAttrGetVal ($paramh;$args_listh;OCI_ATTR_LIST_ARGUMENTS;errhp)
$status:=OCIAttrGetVal ($args_listh;$args_num;OCI_ATTR_NUM_PARAMS;errhp)
Au cas ou
   : ($2=4) `Fonction
      $startloop:=0
      $endloop:=$args_num-1
   : ($2=3) `Procédure
      $startloop:=1
      $endloop:=$args_num
   Sinon
      $endloop:=0
      $endloop:=0
Fin de cas
Boucle ($count;$startloop;$endloop)
   $status:=OCIParamGet ($args_listh;errhp;$argh;$count)
   `récupération du nom du paramètre
   $status:=OCIAttrGetText ($argh;$arg_name;OCI_ATTR_NAME;errhp)
   ` récupération du type du paramètre
   status:=OCIAttrGetVal ($argh;$arg_type;OCI_ATTR_DATA_TYPE;errhp)
   AJOUTER A TABLEAU($3->;$arg_name)
   AJOUTER A TABLEAU($4->;OCI_Lib_External_Type($arg_type))
Fin de boucle

`OCI_DESCRIBE_PACKAGE

C_TEXTE($1) `nom du package à décrire
C_POINTEUR($2) `liste des handles (références) pour chacun des sous-programmes. Utile
`pour retrouver la liste des paramètres de chaque sous-programme
C_POINTEUR($3) `liste des types des sous-programmes (procédures & fonctions) à
`récupérer. 'P' pour Procédure et 'F' pour Fonction
C_POINTEUR($4) `liste de sous-programmes (procédures & fonctions) à récupérer
C_ENTIER LONG($status) `code retour de la fonction OCI
C_ENTIER LONG($count;$endloop)
C_ENTIER LONG($dschp) `handle descripteur
C_ENTIER LONG($paramh)  `handle paramètre
C_ENTIER LONG($progs_listh) `handle sur la liste des sous-programmes
C_ENTIER LONG($progh) `handle sur un sous-programme
C_ENTIER LONG($progs_num) `nombre de sous-programmes
C_TEXTE($prog_name) `nom du sous-programme
C_ENTIER LONG($prog_type) `type du sous-programme, type = 3 alors procédure,
`type = 4 alors fonction

$status:=OCIHandleAlloc(envhp;$dschp;OCI_HTYPE_DESCRIBE)
`5: OCI_PTYPE_PKG
$status:=OCIDescribeAnyText(svchp;errhp;$1;1;OCI_DEFAULT;5;$dschp)
$status:=OCIAttrGetVal($dschp;$paramh;OCI_ATTR_PARAM;errhp)
$status:=OCIAttrGetVal($paramh;$progs_listh;OCI_ATTR_LIST_SUBPROGRAMS; errhp)
`récupération du handle sur la liste des sous-programmes
$status:=OCIAttrGetVal($progs_listh;$progs_num;OCI_ATTR_NUM_PARAMS;errhp) `récupération du nombre de sous-programmes
$endloop:=$progs_num-1
Boucle ($count;0;$endloop)
   `récupération du handle sur un sous-programme
   $status:=OCIParamGet($progs_listh;errhp;$progh;$count)
   `récupération du nom du sous-programme
   $status:=OCIAttrGetText($progh;$prog_name;OCI_ATTR_NAME;errhp)
   `récupération du type du sous-programme
   $status:=OCIAttrGetVal($progh;$prog_type;OCI_ATTR_PTYPE;errhp)
   AJOUTER A TABLEAU($2->;$progh) `stocker le handle sur le sous-programme
   Au cas ou
      :($prog_type=3) `le sous-programme est une Procédure. Mettre 'P'
         AJOUTER A TABLEAU($3->;"P")
      :($prog_type=4) `le sous-programme est une Fonction. Mettre 'F'
         AJOUTER A TABLEAU($3->;"F")
   Fin de cas
   AJOUTER A TABLEAU($4->;$prog_name) `stocker le nom du sous-programme
Fin de boucle